summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ce3d0b70268f8992251965ed72d72672b88fee3f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: ROllerozxa <temporaryemail4meh [gee mail]>
# Contributor: Ivy Foster <ivy.foster@gmail.com>
pkgname='libparserutils-git'
pkgver=0.2.4.r1.gd101b2b
pkgrel=1
pkgdesc='Library for building efficient parsers'
url='http://www.netsurf-browser.org/projects/libparserutils/'
license=('MIT')

makedepends=('git' 'netsurf-buildsystem-git')
provides=('libparserutils')
conflicts=('libparserutils')

arch=('x86_64' 'i686')
source=('git://git.netsurf-browser.org/libparserutils.git')
sha256sums=('SKIP')

pkgver() {
	cd libparserutils
	git describe --long | sed 's:release/::; s:-\([0-9]\+\)-:.r\1.:'
}

prepare() {
	sed 's:-D_BSD_SOURCE::' -i libparserutils/Makefile
}

build() {
	make -C libparserutils PREFIX=/usr INCLUDEDIR=include \
		LIBDIR=lib COMPONENT_TYPE=lib-shared
}

package() {
	cd libparserutils
	make DESTDIR="$pkgdir" PREFIX=/usr INCLUDEDIR=include \
		LIBDIR=lib COMPONENT_TYPE=lib-shared install
	install -Dm644 COPYING \
		"$pkgdir/usr/share/licenses/netsurf/libparserutils"
}