blob: c264aa22570c4f87f05a599507a8172f57a4e49e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Christian Hesse <mail@eworm.de>
pkgname=libpng15
pkgver=1.5.24
pkgrel=1
pkgdesc="A collection of routines used to create PNG format graphics files (1.5 branch)"
arch=('i686' 'x86_64')
url="http://www.libpng.org/pub/png/libpng.html"
license=('custom')
depends=('zlib')
conflicts=('libpng<1.6')
options=('!libtool')
validpgpkeys=('8048643BA2C840F4F92A195FF54984BFA16C640F')
source=("http://downloads.sourceforge.net/sourceforge/libpng/libpng-${pkgver}.tar.xz"{,.asc}
"http://downloads.sourceforge.net/sourceforge/libpng-apng/libpng-${pkgver}-apng.patch.gz")
sha256sums=('b92e3474f3136b5d9443ba92822154ebc2573fc6feead90d364ee9ebc3741be2'
'SKIP'
'830ebd4f2d58f9b7b9e6e9e686d0da3f027e4760a761d78f108479fad54f46af')
build() {
cd libpng-${pkgver}
# Add animated PNG (apng) support
# see http://sourceforge.net/projects/libpng-apng/
patch -p1 -i ../libpng-${pkgver}-apng.patch
./configure --prefix=/usr
make
}
package() {
cd libpng-${pkgver}
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}/usr/"{bin,include,lib/{pkgconfig,libpng.so,libpng.a},share}
}
|