PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libproxy-git
pkgver=r879.g5d5e13d
pkgrel=1
pkgdesc="A library that provides automatic proxy configuration management"
arch=('i686' 'x86_64')
url="https://libproxy.github.io/libproxy/"
license=('LGPL')
depends=('glibc' 'glib2' 'dbus')
makedepends=('git' 'cmake' 'perl' 'python' 'webkit2gtk')
provides=('libproxy')
conflicts=('libproxy')
options=('staticlibs')
source=("git+https://github.com/libproxy/libproxy.git")
sha256sums=('SKIP')


pkgver() {
  cd "libproxy"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "libproxy"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DBIPR=OFF \
    -DPERL_VENDORINSTALL=ON \
    -DWITH_WEBKIT3=ON \
    ./
  make -C "_build"
}

check() {
  cd "libproxy"

  make -C "_build" test
}

package() {
  cd "libproxy"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libproxy"
}