summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f2b80bb605873296ff83af85efc24ca0ae0bde33 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
# Maintainer: Alexey D. <lq07829icatm@rambler.ru>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=libpulse-nosystemd
_pkgbase=pulseaudio
pkgdesc="Client library for PulseAudio"
pkgver=6.0
pkgrel=1
arch=(i686 x86_64)
url="http://www.freedesktop.org/wiki/Software/PulseAudio"
license=(LGPL)
depends=(dbus libasyncns libcap libxtst libsm libsndfile json-c)
makedepends=(libasyncns libcap attr libxtst libsm libsndfile libtool rtkit
             speexdsp tdb dbus avahi bluez bluez-libs gconf intltool jack2-dbus sbc
             lirc openssl xenstore fftw orc json-c gtk3 webrtc-audio-processing
             check)
optdepends=('alsa-plugins: ALSA support'
            'avahi: zeroconf support')
provides=("libpulse=${pkgver}")
conflicts=('libpulse')
replaces=('libpulse')
backup=(etc/pulse/client.conf)
options=(!emptydirs)
source=(http://freedesktop.org/software/$_pkgbase/releases/$_pkgbase-$pkgver.tar.xz)
sha256sums=('b50640e0b80b1607600accfad2e45aabb79d379bf6354c9671efa2065477f6f6')

prepare() {
  cd $_pkgbase-$pkgver
}

build() {
  cd $_pkgbase-$pkgver

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --localstatedir=/var \
    --with-udev-rules-dir=/usr/lib/udev/rules.d \
    --with-database=tdb \
    --disable-tcpwrap \
    --disable-bluez4 \
    --disable-samplerate \
    --disable-rpath \
    --disable-default-build-tests \
    --disable-systemd-daemon \
    --disable-systemd-login \
    --disable-systemd-journal

  # fight unused direct deps
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $_pkgbase-$pkgver
  make -j1 DESTDIR="$pkgdir"/temp install

  mkdir -p "$pkgdir"/{etc/pulse,usr/{bin,lib/pulseaudio,share/man/man{1,5}}}

  mv {"$pkgdir"/temp,"$pkgdir"}/etc/pulse/client.conf

  mv "$pkgdir"/temp/usr/bin/pa{cat,ctl,dsp,mon,play,rec,record} \
     "$pkgdir/usr/bin"

  mv "$pkgdir"/temp/usr/lib/libpulse{,-simple,-mainloop-glib}.so* \
     "$pkgdir/usr/lib"

  mv "$pkgdir"/temp/usr/lib/pulseaudio/libpulsedsp.so \
     "$pkgdir"/temp/usr/lib/pulseaudio/libpulsecommon-*.so \
     "$pkgdir/usr/lib/pulseaudio"

  mv {"$pkgdir"/temp,"$pkgdir"}/usr/lib/cmake
  mv {"$pkgdir"/temp,"$pkgdir"}/usr/lib/pkgconfig

  mv {"$pkgdir"/temp,"$pkgdir"}/usr/include

  mv "$pkgdir"/temp/usr/share/man/man1/pa{cat,ctl,dsp,play}.1 \
     "$pkgdir/usr/share/man/man1"

  mv {"$pkgdir"/temp,"$pkgdir"}/usr/share/man/man5/pulse-client.conf.5
  mv {"$pkgdir"/temp,"$pkgdir"}/usr/share/vala

  rm -rf "$pkgdir"/temp
}