blob: 5bd4fc7d1d113b53130a7e3231a0fd3a84adac26 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
pkgname=librepo
pkgver=1.14.2
pkgrel=1
pkgdesc="Repodata downloading library"
arch=('i686' 'x86_64')
url="https://github.com/rpm-software-management/$pkgname"
license=('LGPL2.1')
depends=('curl>=7.52.0' 'glib2' 'gpgme' 'libxml2' 'openssl' 'zchunk>=0.9.11')
makedepends=('cmake>=3.13' 'python')
checkdepends=('check' 'python-gpgme' 'python-pyxattr' 'python-requests')
optdepends=('python: for python bindings')
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('436ead59dd22f45e87b4c0a408e100e0a159f825128b875ad33ed672204023be')
build() {
cd "$pkgname-$pkgver"
cmake -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_C_FLAGS_RELEASE='-DNDEBUG' \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DENABLE_DOCS=OFF \
-DENABLE_PYTHON=ON \
-DWITH_ZCHUNK=ON
make -C build
}
check() {
cd "$pkgname-$pkgver"
make -C build ARGS="-V" test
}
package() {
cd "$pkgname-$pkgver"
make -C build DESTDIR="$pkgdir/" install
install -Dp -m644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ft=sh ts=4 sw=4 noet:
|