PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: wins1ey <wins1ey at wins1ey dot win>
# Maintainer: EXtremeExploit <pedro.montes.alcalde at gmail dot com>
# Maintainer: Loomeh <loomeh at proton dot me>
pkgname=libresplit-git
_pkgname=libresplit
pkgver=r532.a685f3e49
pkgrel=1
pkgdesc="Free speedrun timer with auto splitting and load removal."
arch=('x86_64')
url='https://libresplit.org'
license=('GPL-3.0-or-later')
depends=(
    'gtk3'
    'jansson'
    'luajit'
)
makedepends=(
    'git'
    'meson'
)
provides=("$_pkgname")
conflicts=("$_pkgname")

source=("$_pkgname::git+https://github.com/LibreSplit/LibreSplit.git")
sha256sums=('SKIP')

pkgver() {
    cd $_pkgname
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=9 HEAD)"
}

build() {
    cd $_pkgname
    arch-meson . build
    meson compile -C build
}

package() {
    cd $_pkgname
    meson install -C build --destdir "$pkgdir"
}