blob: a385587f4961158e1fa0c9517cc2ba750227ded6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
# Maintainer: Alexandre Bouvier <contact@amb.tf>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
_pkgname=libretro-dolphin
pkgname=$_pkgname-git
pkgver=r45471.1802842
pkgrel=1
pkgdesc="Nintendo GameCube/Wii core"
arch=('x86_64')
url="https://github.com/libretro/dolphin"
license=('GPL-2.0-or-later')
groups=('libretro')
depends=(
'enet'
'glibc'
'glslang'
'libretro-core-info'
'libx11'
'libxi'
'pugixml'
)
makedepends=(
'bluez-libs'
'bzip2'
'cmake'
'curl'
'fmt'
'git'
'hidapi'
'libgl'
'libspng'
'libsystemd'
'libusb'
'lz4'
'lzo'
'mbedtls2'
'minizip-ng'
'python'
'sfml'
'vulkan-headers'
'xorgproto'
'xxhash'
'xz'
'zlib'
'zstd'
)
provides=("$_pkgname=${pkgver#r}")
conflicts=("$_pkgname")
source=(
"$_pkgname::git+$url.git"
"cpp-ipc::git+https://github.com/mutouyun/cpp-ipc.git"
"cpp-optparse::git+https://github.com/weisslj/cpp-optparse.git"
"imgui::git+https://github.com/ocornut/imgui.git"
"implot::git+https://github.com/epezent/implot.git"
"tinygltf::git+https://github.com/syoyo/tinygltf.git"
"vulkan-memory-allocator::git+https://github.com/GPUOpen-LibrariesAndSDKs/VulkanMemoryAllocator.git"
"watcher::git+https://github.com/e-dant/watcher.git"
)
b2sums=('SKIP'{,,,,,,,})
pkgver() {
cd $_pkgname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd $_pkgname
git config submodule.Externals/cpp-ipc/cpp-ipc.url ../cpp-ipc
git config submodule.Externals/cpp-optparse/cpp-optparse.url ../cpp-optparse
git config submodule.Externals/imgui/imgui.url ../imgui
git config submodule.Externals/implot/implot.url ../implot
git config submodule.Externals/tinygltf/tinygltf.url ../tinygltf
git config submodule.Externals/VulkanMemoryAllocator.url ../vulkan-memory-allocator
git config submodule.Externals/watcher/watcher.url ../watcher
git -c protocol.file.allow=always submodule update
}
build() {
local options=(
-D CMAKE_BUILD_TYPE=Release
-D CMAKE_C_FLAGS_RELEASE="-DNDEBUG"
-D CMAKE_CXX_FLAGS_RELEASE="-DNDEBUG"
-D ENABLE_LTO=OFF
-D LIBRETRO=ON
-Wno-dev
)
cmake "${options[@]}" -B build -S $_pkgname
cmake --build build
}
package() {
depends+=(
'libbluetooth.so'
'libbz2.so'
'libcurl.so'
'libEGL.so'
'libfmt.so'
'libgcc_s.so'
'libGLX.so'
'libhidapi-hidraw.so'
'liblz4.so'
'liblzma.so'
'liblzo2.so'
'libmbedcrypto.so'
'libmbedtls.so'
'libmbedx509.so'
'libsfml-network.so'
'libspng.so'
'libstdc++.so'
'libusb-1.0.so'
'libxxhash.so'
'libz.so'
'libzstd.so'
)
# shellcheck disable=SC2154
install -D -t "$pkgdir"/usr/lib/libretro build/dolphin_libretro.so
}
|