PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Alexandre Bouvier <contact@amb.tf>
_pkgname=libretro-ecwolf
pkgname=$_pkgname-git
pkgver=r1762.18eca17
pkgrel=1
pkgdesc="Wolfenstein 3D core"
arch=('aarch64' 'armv7h' 'i486' 'i686' 'pentium4' 'x86_64')
url="https://github.com/libretro/ecwolf"
license=('BSD' 'LGPL')
groups=('libretro')
depends=('gcc-libs' 'glibc' 'libretro-core-info')
makedepends=('git')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=(
	"$_pkgname::git+$url.git"
	'libretro-common::git+https://github.com/libretro/libretro-common.git'
)
b2sums=(
	'SKIP'
	'SKIP'
)

pkgver() {
	cd $_pkgname
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd $_pkgname
	git config submodule.src/libretro/libretro-common.url ../libretro-common
	git -c protocol.file.allow=always submodule update
	sed -i 's/-O[0123s]//' src/libretro/Makefile
}

build() {
	make -C $_pkgname/src/libretro
}

package() {
	cd $_pkgname
	# shellcheck disable=SC2154
	install -D -t "$pkgdir"/usr/lib/libretro src/libretro/ecwolf_libretro.so
	install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname docs/license-{id,mame}.txt
}