blob: fb6a54963eaac656b1059b56a2914b0d96b055cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Alexandre Bouvier <contact@amb.tf>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
_reponame=flycast
_pkgname=libretro-$_reponame
pkgname=$_pkgname-git
pkgver=2.1.r70.g415d8c2ea
pkgrel=1
pkgdesc="Sega Dreamcast/NAOMI/NAOMI 2/Atomiswave core (fork of reicast)"
arch=('aarch64' 'armv7h' 'i486' 'i686' 'pentium4' 'x86_64')
url="https://github.com/flyinghead/flycast"
license=('GPL2')
groups=('libretro')
depends=('gcc-libs' 'glibc' 'glslang>=11.13' 'libretro-core-info' 'zlib')
makedepends=(
'cmake'
'git'
'glm'
'libchdr'
'libgl'
'libzip'
'miniupnpc'
'vulkan-headers>=1:1.3.236'
'vulkan-icd-loader'
'xbyak'
'xxhash'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=(
"$_reponame::git+$url.git"
'VulkanMemoryAllocator::git+https://github.com/GPUOpen-LibrariesAndSDKs/VulkanMemoryAllocator.git'
'unbundle-libs.patch'
)
b2sums=(
'SKIP'
'SKIP'
'46548c4be0e6bdebaece4b3484fd6d05015a7cb07cef5054d25fe8df95ef1855eceea39ec3becd13e64e4753c7badcfb18a1b1f5eeedbb720f3c38c1cb0dc996'
)
pkgver() {
cd $_reponame
git describe --long --tags | sed 's/^v//i;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd $_reponame
git config submodule.core/deps/VulkanMemoryAllocator.url ../VulkanMemoryAllocator
git -c protocol.file.allow=always submodule update
git revert -n 8d0654c323028d9d31f67c51d65e99b410a91750
patch -Np1 < ../unbundle-libs.patch
rm -r core/deps/libretro-common/include/libchdr
}
build() {
cmake -S $_reponame -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_C_FLAGS_RELEASE="-DNDEBUG" \
-DCMAKE_CXX_FLAGS_RELEASE="-DNDEBUG" \
-DCMAKE_INSTALL_BINDIR=lib/libretro \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIBRETRO=ON \
-Wno-dev
cmake --build build
}
package() {
depends+=(
'libchdr.so'
'libGL.so'
'libminiupnpc.so'
'libxxhash.so'
'libzip.so'
)
# shellcheck disable=SC2154
DESTDIR="$pkgdir" cmake --install build
}
|