blob: e2bb4f2a58786a8e8d7b9fd6c634f3b4ecbe393d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Alexandre Bouvier <contact@amb.tf>
# Contributor: Oliver Jaksch <arch-aur at com-in dot de>
# Contributor: Mike Polvere <mic.tjs@gmail.com>
# Contributor: Michael DeGuzis <mdeguzis@gmail.com>
# Contributor: Lauri Niskanen <ape@ape3000.com>
_pkgname=libretro-gambatte
pkgname=$_pkgname-git
pkgver=r1082.9fe223d
pkgrel=1
epoch=1
pkgdesc="Nintendo Game Boy/Game Boy Color core"
arch=('aarch64' 'armv7h' 'i486' 'i686' 'pentium4' 'x86_64')
url="https://github.com/libretro/gambatte-libretro"
license=('GPL-2.0-only')
groups=('libretro')
depends=('glibc' 'libretro-core-info')
makedepends=('git' 'libstdc++')
provides=("$_pkgname=${pkgver#r}")
conflicts=("$_pkgname")
source=("$_pkgname::git+$url.git")
b2sums=('SKIP')
pkgver() {
cd $_pkgname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd $_pkgname
# remove hardcoded optimization flags
sed -Ei 's/-O([0123s]|fast)//' Makefile.libretro
}
build() {
cd $_pkgname
make
}
package() {
depends+=('libstdc++.so')
cd $_pkgname
# shellcheck disable=SC2154
install -D -t "$pkgdir"/usr/lib/libretro gambatte_libretro.so
}
|