blob: 7289822cd95dc8503101b26cdea18378343de726 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: Alexandre Bouvier <contact@amb.tf>
_pkgname=libretro-pcsx2
pkgname=$_pkgname-git
pkgver=r16875.7357bde45
pkgrel=1
pkgdesc="Sony PlayStation 2 core"
arch=('x86_64')
url="https://github.com/libretro/pcsx2"
license=('GPL3')
groups=('libretro')
depends=(
'fmt'
'gcc-libs'
'glibc'
'libaio'
'libpng'
'libretro-core-info'
'libzip'
'rapidyaml'
'systemd-libs'
'xz'
'zlib'
'zstd'
)
makedepends=(
'cmake'
'fast_float'
'ffmpeg'
'git'
'sdl2'
'soundtouch'
)
provides=("$_pkgname=${pkgver#r}")
conflicts=("$_pkgname")
source=(
"$_pkgname::git+$url.git#branch=libretro"
'glslang::git+https://github.com/KhronosGroup/glslang.git'
'libchdr::git+https://github.com/rtissera/libchdr.git'
'vulkan-headers::git+https://github.com/KhronosGroup/Vulkan-Headers.git'
)
b2sums=(
'SKIP'
'SKIP'
'SKIP'
'SKIP'
)
pkgver() {
cd $_pkgname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd $_pkgname
git config submodule.3rdparty/glslang/glslang.url ../glslang
git config submodule.3rdparty/libchdr/libchdr.url ../libchdr
git config submodule.3rdparty/vulkan-headers.url ../vulkan-headers
git -c protocol.file.allow=always submodule update
sed -i '/ccache/d' CMakeLists.txt
sed -i '/USE_GCC/s/AND CMAKE_INTERPROCEDURAL_OPTIMIZATION//' common/CMakeLists.txt
sed -i '/USE_SYSTEM_LIBS OFF/d' cmake/BuildParameters.cmake
}
build() {
cmake -S $_pkgname -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_C_FLAGS_RELEASE="-DNDEBUG" \
-DCMAKE_CXX_FLAGS_RELEASE="-DNDEBUG" \
-DCMAKE_DISABLE_PRECOMPILE_HEADERS=ON \
-DDISABLE_ADVANCE_SIMD=ON \
-DLIBRETRO=ON \
-DUSE_SYSTEM_LIBS=ON \
-Wno-dev
cmake --build build
}
package() {
# shellcheck disable=SC2154
install -Dm644 -t "$pkgdir"/usr/lib/libretro build/bin/pcsx2_libretro.so
}
|