blob: 3db0e416c35a415acba862e7cf4bdeb9bbcc163a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
# Maintainer: Wouter Wijsman <wwijsman@live.nl>
# Maintainer original package: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Duck Hunt <vaporeon@tfwno.gf>
pkgname=libretro-ppsspp-gameros
pkgver=28196
pkgrel=1
pkgdesc='Sony PlayStation Portable core with all required assets'
arch=(x86_64)
url=https://github.com/libretro/ppsspp
license=(GPL2)
groups=(libretro)
depends=(
gcc-libs
glew
glibc
libgl
libpng
libretro-core-info
libzip
snappy
zlib
)
makedepends=(
cmake
git
libglvnd
python
)
conflicts=(
libretro-ppsspp
)
_commit=f0ea814107e3c29fc3c961195765e9148fa97fdd
source=(
libretro-ppsspp::git+https://github.com/hrydgard/ppsspp.git#commit=${_commit}
git+https://github.com/Kingcom/armips.git
git+https://github.com/discordapp/discord-rpc.git
git+https://github.com/hrydgard/ppsspp-ffmpeg.git
ppsspp-glslang::git+https://github.com/hrydgard/glslang.git
git+https://github.com/hrydgard/ppsspp-lang.git
ppsspp-miniupnp::git+https://github.com/hrydgard/miniupnp.git
git+https://github.com/Tencent/rapidjson.git
git+https://github.com/KhronosGroup/SPIRV-Cross.git
armips-tinyformat::git+https://github.com/Kingcom/tinyformat.git
libretro.cpp.patch
)
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd libretro-ppsspp
git rev-list --count HEAD
}
prepare() {
cd libretro-ppsspp
patch -p1 libretro/libretro.cpp < ../libretro.cpp.patch
for submodule in ffmpeg assets/lang ext/glslang ext/miniupnp; do
git submodule init ${submodule}
git config submodule.${submodule}.url ../ppsspp-${submodule#*/}
git submodule update ${submodule}
done
for submodule in ext/{armips,discord-rpc,rapidjson,SPIRV-Cross}; do
git submodule init ${submodule}
git config submodule.${submodule}.url ../${submodule#*/}
git submodule update ${submodule}
done
cd ext/armips
for submodule in ext/tinyformat; do
git submodule init ${submodule}
git config submodule.${submodule}.url ../../../armips-${submodule#*/}
git submodule update ${submodule}
done
}
build() {
cmake -S libretro-ppsspp -B build \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_SKIP_RPATH=ON \
-DOpenGL_GL_PREFERENCE=GLVND \
-DHEADLESS=OFF \
-DLIBRETRO=ON \
-DMOBILE_DEVICE=OFF \
-DSIMULATOR=OFF \
-DUNITTEST=OFF \
-DUSE_SYSTEM_LIBZIP=ON \
-DUSE_SYSTEM_SNAPPY=ON \
-DUSING_QT_UI=OFF
make -C build
}
package() {
install -Dm 644 build/lib/ppsspp_libretro.so -t "${pkgdir}"/usr/lib/libretro/
install -Dm 644 libretro-ppsspp/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/libretro-ppsspp-git/
mkdir -p "${pkgdir}"/usr/share/libretro/bios/ppsspp/
cp -r build/assets "${pkgdir}"/usr/share/libretro/bios/ppsspp/
}
# vim: ts=2 sw=2 et:
|