summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d51dd215a53685c83aad53281f903768be2f3ba4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Contributor: Lex Black <autumn-wind at web dot de>
# Contributor: Daniel Micay <danielmicay@gmail.com>

pkgname=libseccomp-git
pkgver=2.5.4.r126.gf1c3196
pkgrel=1
pkgdesc="Interface to the Linux Kernel's syscall filtering mechanism"
arch=('i686' 'x86_64')
url="https://github.com/seccomp/libseccomp"
license=('LGPL')
depends=('glibc')
makedepends=('git' 'gperf')
provides=("libseccomp=$pkgver" 'libseccomp.so')
conflicts=('libseccomp')
options=('staticlibs')
source=("git+https://github.com/seccomp/libseccomp.git")
sha256sums=('SKIP')


pkgver() {
  cd "libseccomp"

  _tag=$(git tag -l --sort -v:refname | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "libseccomp"

  ./autogen.sh
  ./configure \
    --prefix="/usr"
  make
}

check() {
  cd "libseccomp"

  #make check
}

package() {
  cd "libseccomp"

  make DESTDIR="$pkgdir" install
}