blob: 2874160cb475946e605d6e2915fe41990b2cd178 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Bruno Pagani <archange@archlinux.org>
# Maintainer: Baptiste Jonglez <archlinux at bitsofnetworks dot org>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>
pkgname=libsecp256k1
_gitcommit=d7838ba6a6ac77cec173080f20efcd0e311ebfaa
pkgver=20200919+1172+gd7838ba
pkgrel=1
pkgdesc="Optimized C library for EC operations on curve secp256k1"
arch=(x86_64)
url="https://github.com/bitcoin-core/secp256k1"
license=(MIT)
depends=(gmp)
source=(${url}/archive/${_gitcommit}/${pkgname}-${pkgver}.tar.gz)
sha256sums=('9446f2d6d4cdf476f68b95493ae990bbec201d208cbe24b2fd14e0452acb2648')
prepare() {
cd secp256k1-${_gitcommit}
autoreconf -vfi
}
build() {
cd secp256k1-${_gitcommit}
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--libexecdir=/usr/bin \
--sysconfdir=/etc \
--sharedstatedir=/usr/share/libsecp256k1 \
--localstatedir=/var/lib/libsecp256k1 \
--disable-static \
--disable-benchmark \
--disable-coverage \
--enable-module-recovery \
--enable-tests \
--enable-exhaustive-tests \
--disable-openssl-tests \
--with-gnu-ld
make
}
check() {
cd secp256k1-${_gitcommit}
make check
}
package() {
cd secp256k1-${_gitcommit}
make DESTDIR="${pkgdir}" install
install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}
|