blob: 59198beef004df5622d9621f68a6f68621f6f8f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libshout-git
pkgver=2.4.6.r0.gd8592a0
pkgrel=1
pkgdesc="Library for accessing a shoutcast/icecast server"
arch=('i686' 'x86_64')
url="https://libshout.freedesktop.org/wiki/"
license=('GPL2')
depends=('glibc' 'openssl' 'libtheora' 'libvorbis' 'speex' )
makedepends=('git')
provides=("libshout=$pkgver")
conflicts=('libshout')
options=('staticlibs')
source=("git+https://gitlab.xiph.org/xiph/icecast-libshout.git")
sha256sums=('SKIP')
prepare() {
cd "icecast-libshout"
sed -i 's|url = \.\.|url = https://gitlab.xiph.org/xiph|' ".gitmodules"
git submodule sync
git submodule update --init --recursive
}
pkgver() {
cd "icecast-libshout"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "icecast-libshout"
./autogen.sh
./configure \
--prefix="/usr"
make
}
package() {
cd "icecast-libshout"
make DESTDIR="$pkgdir" install
rm "$pkgdir/usr/share/doc/libshout/COPYING"
}
|