PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
_pkgname=libsigmf
pkgname=$_pkgname-git
pkgver=r13.8ac7dbc
pkgrel=2
pkgdesc="A header-only C++ library for working with SigMF metadata"
arch=(any)
url="https://github.com/deepsig/libsigmf"
license=('Apache')
depends=()
makedepends=('cmake' 'git' 'flatbuffers' 'nlohmann-json')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+$url.git"
        "0001-cmake-fix-installation-of-fbs-files.patch"
        "0002-fix-for-flatbuffers-v2.patch"
)
sha256sums=('SKIP'
            '03012d41f55c1a2f7a61f952c79d14e80bba1f2ee508d77a3d94fe78f3ab394c'
            '9eae8483e26085999654ef9a633648b7025eca2c7a16b19b471ad7c189c47e04')

pkgver() {
	cd "$_pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "$_pkgname"
	patch -p1 < "$srcdir/0001-cmake-fix-installation-of-fbs-files.patch"
	patch -p1 < "$srcdir/0002-fix-for-flatbuffers-v2.patch"
}

build() {
	cmake -B build -S "$_pkgname" \
		-Wno-dev \
		-DCMAKE_BUILD_TYPE='None' \
		-DUSE_SYSTEM_FLATBUFFERS=ON \
		-DUSE_SYSTEM_JSON=ON \
		-DCMAKE_INSTALL_PREFIX=/usr
	make -C build
}

package() {
	make -C build DESTDIR="$pkgdir/" install
}