blob: 3ba0e0f7cc537fe4fa66100a2ca4d537e1271ae0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libsmbios-git
pkgver=2.4.3.r3.gf01a217
pkgrel=2
pkgdesc="Library for interacting with SMBIOS tables"
arch=('i686' 'x86_64')
url="https://github.com/dell/libsmbios"
license=('GPL' 'custom')
depends=('glibc')
makedepends=('git' 'libxml2' 'python')
optdepends=('python: tools')
provides=("libsmbios=$pkgver")
conflicts=('libsmbios')
options=('staticlibs')
source=("git+https://github.com/dell/libsmbios.git")
sha256sums=('SKIP')
pkgver() {
cd "libsmbios"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "libsmbios"
./autogen.sh --no-configure
./configure \
--prefix="/usr" \
--sbindir="/usr/bin" \
--sysconfdir="/etc"
make
}
check() {
cd "libsmbios"
make check
}
package() {
cd "libsmbios"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING{,-OSL} -t "$pkgdir/usr/share/licenses/libsmbios"
}
|