PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Aleksy Grabowski <hurufu@gmail.com>

pkgname=libsocket-git
pkgver=2.5.0.r25.g706649c
pkgrel=1
pkgdesc='Library with a C part and a C++ part making sockets usage easy and clean'
arch=('i686' 'x86_64')
url='http://dermesser.github.io/libsocket/doc/'
license=('BSD-2-Clause')

makedepends=(
    git
    cmake
)
provides=(
    libsocket
    libsocket++.so=libsocket++.so-64
    libsocket.so=libsocket.so-64
)
conflicts=(
    libsocket
)

source=(
    'git+https://github.com/dermesser/libsocket.git'
)
md5sums=(
    'SKIP'
)

pkgver() {
    git -C "$srcdir/libsocket" describe | awk -F - '{ print substr($1,2)".r"$2"."$3 }'
}

build() {
    mkdir -p libsocket/build
    cd libsocket/build
    cmake \
        -Wno-dev \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DBUILD_STATIC_LIBS=ON \
        ..
    make
}

package() {
    make -C libsocket/build DESTDIR="$pkgdir" install
    install -Dm644 "$srcdir/libsocket/LICENSE" "$pkgdir/usr/share/licenses/libsocket/LICENSE"
    mkdir -p "$pkgdir/usr/share/doc/libsocket"
    cp -rt "$pkgdir/usr/share/doc/libsocket" "$srcdir"/libsocket/examples*
}