blob: 6422f64b6ab52a78bf777e1e58309762aae0ff7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Luis Aranguren <pizzaman@hotmail.com>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: namelessjon <jonathan.stott@gmail.com>
# Contributor: Alessio Sergi <asergi at archlinux dot us>
pkgname=libsodium-static
_pkgname=libsodium
pkgver=1.0.22
pkgrel=1
pkgdesc="P(ortable|ackageable) NaCl-based crypto library (static library)"
arch=('i686' 'x86_64')
url="https://github.com/jedisct1/libsodium"
license=('custom:ISC')
depends=()
optdepends=('libsodium: headers and pkg-config files')
source=(https://download.libsodium.org/libsodium/releases/$_pkgname-$pkgver.tar.gz)
sha512sums=('8f392de781f09578d9a32000a4198e8d199ab910743017af3b3c5cae8053f745bcc885a9417fcaffb03b832400d829aef3a93c065bbb77b92598d882b6dcf187')
options=('staticlibs')
build() {
cd "$_pkgname-$pkgver"
./configure --prefix=/usr --disable-pie
make
}
check() {
cd "$_pkgname-$pkgver"
make check
}
package() {
cd "$_pkgname-$pkgver"
make DESTDIR="$pkgdir" install
rm -rf "$pkgdir/usr/include/"
rm -f "$pkgdir/usr/lib/"*.so*
rm -rf "$pkgdir/usr/lib/pkgconfig"
# install license
install -d -m 755 "$pkgdir/usr/share/licenses/$pkgname"
install -m 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|