blob: 518872b5f8772a74c6881c8b93a0eb094f0cfafe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
pkgname=libsolv
pkgver=0.6.23
pkgrel=2
pkgdesc="Library for solving packages and reading repositories"
arch=('i686' 'x86_64')
url="https://github.com/openSUSE/$pkgname"
license=('BSD')
depends=('expat' 'xz' 'zlib')
makedepends=('cmake' 'perl' 'python' 'rpm-org' 'ruby' 'swig')
optdepends=('perl: for perl bindings'
'python: for python bindings'
'ruby: for ruby bindings')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
md5sums=('80098e081712368d38ade6affb39dd65')
prepare() {
cd "$pkgname-$pkgver"
rm -rf build
mkdir build
}
build() {
cd "$pkgname-$pkgver"/build
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB=/lib \
-DUSE_VENDORDIRS=ON \
-DFEDORA=1 \
-DENABLE_APPDATA=ON \
-DENABLE_ARCHREPO=ON \
-DENABLE_BZIP2_COMPRESSION=ON \
-DENABLE_COMPLEX_DEPS=1 \
-DENABLE_COMPS=ON \
-DENABLE_CUDFREPO=OFF \
-DENABLE_DEBIAN=ON \
-DENABLE_HAIKU=OFF \
-DENABLE_HELIXREPO=ON \
-DENABLE_LZMA_COMPRESSION=ON \
-DENABLE_MDKREPO=ON \
-DENABLE_PERL=ON \
-DENABLE_PUBKEY=OFF \
-DENABLE_PYTHON=ON \
-DENABLE_RPMDB=ON \
-DENABLE_RPMDB_BYRPMHEADER=ON \
-DENABLE_RPMMD=ON \
-DENABLE_RUBY=ON \
-DENABLE_SUSEREPO=ON \
-DMULTI_SEMANTICS=ON \
..
make
}
check() {
cd "$pkgname-$pkgver"/build
make ARGS="-V" test
}
package() {
cd "$pkgname-$pkgver"/build
make DESTDIR="$pkgdir/" install
install -D -m644 ../LICENSE.BSD "$pkgdir/usr/share/licenses/$pkgname/LICENSE.BSD"
install -D -m644 ../README "$pkgdir/usr/share/doc/$pkgname/README"
install -D -m644 ../BUGS "$pkgdir/usr/share/doc/$pkgname/BUGS"
}
# vim: set ft=sh ts=4 sw=4 noet:
|