summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e15b5c5e1d89dbb87f470383e7e880bb69b57a5f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
# Maintainer: Richard Weber <old-box at outlook dot com>
# Contributor: Benjamin Hedrich <kiwisauce at pagenotfound dot de>
# Contributor: Thomas Jost <schnouki at schnouki dot net>
# Contributor: Tomas Strand <tomas at fik1 dot net>
pkgname=libspotify
pkgver=12.1.51
pkgrel=3
pkgdesc="C API package allowing third-party developers to write applications that utilize the Spotify music streaming service"
arch=(i686 x86_64 armv7h armv6h)
url="https://developer.spotify.com/technologies/libspotify/"
license=('custom')
depends=('glibc')

if [ "$CARCH" == "armv6h" ]; then
    pkgver=12.1.103
    SPOTIFY_ARCH="armv6-bcm2708hardfp"
    md5sums=('bf9afc8c7b966841735734b248f9c7a7')
    sha256sums=('d658e6c1978fb46cf33376eb8367a51d024f4014f21beac1dd264532bcc54b24')
fi

if [ "$CARCH" == "armv7h" ]; then
    SPOTIFY_ARCH="armv7"
    md5sums=('eb7e98849b3bb6d364fa74034602afbf')
    sha256sums=('ad27b6c5aee5382b66b39bfea3b1752076b7abcc445979ce25c1ec9d7ff3aeda')
fi

if [ "$CARCH" == "x86_64" ]; then
    SPOTIFY_ARCH="x86_64"
    md5sums=('83efddcc195d6ff12b24c97c767a5e45')
    sha256sums=('43a14e0732ba6ae30078fac105d0e2998d04d5f5c396a4968386bc4e22491058')
fi

if [ "$CARCH" == "i686" ]; then
    SPOTIFY_ARCH="i686"
    md5sums=('04735b890da0b1fc7f1f14e68a5293de')
    sha256sums=('941ab4ba10bcd6ec4e96127afd095a39e11bc955de0882734c97e4f588b155ae')

fi

source=(http://developer.spotify.com/download/libspotify/libspotify-${pkgver}-Linux-${SPOTIFY_ARCH}-release.tar.gz)

build() {
    cd "$srcdir/$pkgname-$pkgver-Linux-${SPOTIFY_ARCH}-release"

    # Don't do stupid things from a Makefile
    msg2 "Patching Makefile..."
    sed -i 's/ldconfig//' Makefile
}

package() {
    cd "$srcdir/$pkgname-$pkgver-Linux-${SPOTIFY_ARCH}-release"

    make prefix="$pkgdir/usr" install

    # Install documentation
    cp -R share "$pkgdir"/usr/share
    mkdir -p "$pkgdir"/usr/share/man
    mv "$pkgdir"/usr/share/man3 "$pkgdir"/usr/share/man/man3

    # Correct pkgconfig file
    sed -e s:PKG_PREFIX:/usr:g \
          < lib/pkgconfig/libspotify.pc \
          > "$pkgdir"/usr/lib/pkgconfig/libspotify.pc

    # Custom license
    install -Dm644 LICENSE licenses.xhtml "$pkgdir"/usr/share/doc/libspotify
    mkdir -p "$pkgdir"/usr/share/licenses/libspotify
    ln -s ../../doc/libspotify/LICENSE "$pkgdir"/usr/share/licenses/libspotify/LICENSE
}