summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0151e6be917e18ff248d0fa85f7442dd710c19fe (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Frederik Schwan <freswa at archlinux dot org>

pkgname=libstrophe-git
pkgver=653.2f491e0
pkgrel=1
pkgdesc='A simple, lightweight C library for writing XMPP clients'
arch=('x86_64')
url='http://strophe.im/libstrophe/'
license=('MIT' 'GPL3')
depends=('expat' 'openssl')
makedepends=('git' 'doxygen')
checkdepends=('check')
provides=('libstrophe')
conflicts=('libstrophe')
options=('staticlibs')
source=('git://github.com/strophe/libstrophe.git')
b2sums=('SKIP')

pkgver() {
	cd libstrophe
	echo $(git rev-list --count master).$(git rev-parse --short master)
}

build() {
	cd libstrophe

	./bootstrap.sh
	./configure --prefix=/usr
	make
	doxygen
}

check() {
	cd libstrophe
	make check
}

package() {
	cd libstrophe
	make DESTDIR="${pkgdir}" install

	install -Dm644 -t "${pkgdir}"/usr/share/licenses/libstrophe-git/ MIT-LICENSE.txt
}