PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Mikaela RJ "Qyriad" Szekely <qyriad@gmail.com>
# Special thanks to Pokemod97 for libtransistor-git <3
pkgname=libtransistor-git
pkgver=1.1.0.r256.g383d582
pkgrel=2
pkgdesc="Nintendo Switch homebrew toolchain"
arch=('x86_64')
url="https://github.com/ReSwitched/libtransistor"
license=('ISC')
groups=('base-devel')
depends=('clang'
'lld'
'squashfs-tools'
'python-elftools'
'python-lz4')
makedepends=('git'
'cmake')
provides=("libtransistor")
conflicts=("libtransistor-bin")
options=(!'strip' !'buildflags')
source=("git+https://github.com/ReSwitched/libtransistor.git")
md5sums=("SKIP")

prepare()
{
	cd "$srcdir/libtransistor"
	git submodule update --init --recursive
}

pkgver()
{
	cd "$srcdir/libtransistor"
	git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build()
{
	cd "$srcdir/libtransistor"
	make
}

package()
{
	cd "$srcdir/libtransistor/dist"
	mkdir -p "$pkgdir/opt/libtransistor"
	cp -r * "$pkgdir/opt/libtransistor"
}