blob: c2a44ac6ca6abeb8196cd7bdb8ad9fe63c7dbcf1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Florian Maunier <fmaunier@gmail.com>
pkgname=libu2f-server-git
pkgver=1.0.1.r50.g7485f4e
pkgrel=1
pkgdesc="Yubico Universal 2nd Factor (U2F) Server C Library - git checkout"
arch=('i686' 'x86_64')
url='https://github.com/Yubico/libu2f-server'
license=('BSD')
depends=('openssl' 'json-c')
makedepends=('check' 'git' 'gengetopt')
provides=('libu2f-server')
conflicts=('libu2f-server')
source=('git://github.com/Yubico/libu2f-server.git')
sha256sums=('SKIP')
pkgver() {
cd libu2f-server/
if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
printf '%s.r%s.g%s' \
"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
"$(git rev-list --count ${GITTAG}..)" \
"$(git log -1 --format='%h')"
else
printf '0.r%s.g%s' \
"$(git rev-list --count master)" \
"$(git log -1 --format='%h')"
fi
}
build() {
cd libu2f-server/
autoreconf -fi
./configure \
--prefix=/usr
make
}
check() {
cd libu2f-server/
make check
}
package() {
cd libu2f-server/
make DESTDIR="${pkgdir}/" install
install -D -m0644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|