blob: 39ca6e01c02f4786eeb9b35d61d0fa6f3ccf2a38 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# This package is based on libva-intel-driver just with the hybrid codec flag
# Maintainer: DetMittens
# Contributor: Maxime Gauduin <alucryd@archlinux.org> Maintainer of libva-intel-driver in extra
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
pkgname=libva-intel-driver-hybrid
pkgver=2.2.0
pkgrel=1
pkgdesc='VA-API implementation for Intel G45 and HD Graphics family'
arch=('x86_64')
url='https://01.org/linuxmedia/vaapi'
license=('MIT')
depends=('libva' 'libdrm')
makedepends=('git' 'meson')
replaces=('libva-driver-intel')
optdepends=('intel-hybrid-codec-driver: Provides codecs with partial HW acceleration')
conflicts=('libva-intel-driver')
provides=('libva-intel-driver')
source=("git+https://github.com/intel/intel-vaapi-driver.git#tag=${pkgver}")
sha256sums=('SKIP')
prepare() {
# Only relevant if intel-gpu-tools is installed,
# since then the shaders will be recompiled
sed -i '1s/python$/&2/' intel-vaapi-driver/src/shaders/gpp.py
# Fix undefined variable in src/meson.build
sed -i 's/2.2.0/2.2.0.0/' intel-vaapi-driver/meson.build
}
build() {
arch-meson -Denable_hybrid_codec=true intel-vaapi-driver build
ninja -C build
}
package() {
DESTDIR="${pkgdir}" ninja -C build install
install -Dm 644 intel-vaapi-driver/COPYING -t "${pkgdir}"/usr/share/licenses/libva-intel-driver-hybrid
}
# vim: ts=2 sw=2 et:
|