blob: 812693fe9c7b215f97e6a49d00d4de8ad8c86c9c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Soukyuu <chrno-spheredΘhotmail·com>
# Contributor: revel <revelΘmuub·net>
# Contributor: Stephen Caraher <moskvax@gmail.com>
# Contributor: Uli Armbruster <uli_armbrusterΘweb·de>
# Contributor: Robert Gregor <gimpΘpop·de>
pkgname=libvorbis-aotuv-lancer
_srcname=libvorbis-aotuv
pkgver=b6.03
pkgrel=7
_releasedate=20110424-20150808
_srcrel=2015
pkgdesc='A fork of libvorbis intended to provide better quality sound at low to medium bitrates, with lancer patches to improve performance'
arch=('i686' 'x86_64')
url='https://www.hydrogenaud.io/forums/index.php?showtopic=109766'
license=('BSD')
depends=('libogg')
conflicts=('libvorbis' 'libvorbis-aotuv')
provides=('libvorbis=1.3.5' 'libvorbisfile.so' 'libvorbis.so' 'libvorbisenc.so')
source=("http://www.geocities.jp/aoyoume/aotuv/source_code/${_srcname}_${pkgver}_${_srcrel}.tar.bz2"
"http://freac.org/patches/arch/libvorbis-aotuv_b6.03_2015-lancer.patch"
"http://freac.org/patches/arch/libvorbis-aotuv_b6.03_2015-lancer-x64.patch")
sha256sums=('fba6724d2bc2b6a911a25e60f21a45749d507f181a9e150415ce41e4d03bc08f'
'38a3ad12937c1748a0cfe0779102d6f02824f897a729ce07cc9f658482a6826b'
'e54eb271f539ce7ae3bc90bc85643c79c22925fcd1963920b969d7035eeae653')
prepare() {
cd "aotuv-${pkgver}_${_releasedate}"
chmod +x configure
# apply lancer patches
patch -p1 -i "${srcdir}/libvorbis-aotuv_b6.03_2015-lancer.patch"
# linux x64 uses 8 byte for long - src expects 4
if [ "${CARCH}" = "x86_64" ]; then
patch -p1 -i "${srcdir}/libvorbis-aotuv_b6.03_2015-lancer-x64.patch"
fi
# configure sets their own CFLAGS to increase performance, so we clear makepkg.conf ones
#CFLAGS="march=native"
#CXXFLAGS="march=native"
}
build() {
cd "aotuv-${pkgver}_${_releasedate}"
./configure --prefix=/usr --enable-shared --disable-static
make
}
check() {
cd "aotuv-${pkgver}_${_releasedate}"
make -j1 check
}
package() {
cd "aotuv-${pkgver}_${_releasedate}"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|