blob: 2a60725cf171cbb5ad29e0d7c4810b0c60f1a0ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libwmf-git
pkgver=0.2.13.r4.g1b1c053
pkgrel=1
pkgdesc="A library for reading vector images in Microsoft's native Windows Metafile Format"
arch=('i686' 'x86_64')
url="https://github.com/caolanm/libwmf"
license=('GPL-2.0-or-later')
depends=('glibc' 'expat' 'freetype2' 'gsfonts' 'libjpeg' 'libx11')
makedepends=('git' 'gtk2' 'libxt')
optdepends=('gdk-pixbuf2: for pixbuf loader')
provides=("libwmf=$pkgver")
conflicts=('libwmf')
options=('staticlibs')
source=("git+https://github.com/caolanm/libwmf.git")
sha256sums=('SKIP')
pkgver() {
cd "libwmf"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "libwmf"
autoreconf -fi
./configure \
--prefix="/usr"
make
}
check() {
cd "libwmf"
make check
}
package() {
cd "libwmf"
make DESTDIR="$pkgdir" install
}
|