summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3d81b98c70cb03a3f434475033c911a02bdeea63 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Jan de Groot  <jgc@archlinux.org>
pkgname=libwnck+-git
pkgver=2.31.0.r22.g129f5dc
pkgrel=1
pkgdesc="Window Navigator Construction Kit"
arch=('i686' 'x86_64')
license=('LGPL')
provides=('libwnck=2.31.0' 'libwnck+=2.31.0')
conflicts=('libwnck' 'libwnck+')
depends=('gtk2' 'startup-notification' 'libxres')
makedepends=('git' 'libxt' 'intltool' 'gobject-introspection' 'gnome-common')
url="https://github.com/bbidulock/libwnck"
source=("$pkgname::git+https://github.com/bbidulock/libwnck.git#branch=libwnck+")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --long --tags | sed -r 's,LIBWNCK_,,;s,([^-]*-g),r\1,;s,[-_],.,g'
}

build() {
  cd $pkgname
  ./autogen.sh --prefix=/usr --sysconfdir=/etc \
	--localstatedir=/var --disable-static \
	--enable-tools --enable-gtk-doc
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
  # libwnck3 installs these with the normal names linked against wrong library
  mv "${pkgdir}"/usr/bin/wnckprop "${pkgdir}"/usr/bin/wnckprop2
  mv "${pkgdir}"/usr/bin/wnck-urgency-monitor "${pkgdir}"/usr/bin/wnck-urgency-monitor2
}