blob: ed57505da024c56b525e494178eec11f5b71e2e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libx11-git
pkgver=1.8.4.r14.g96cbac89
pkgrel=1
pkgdesc="Core X11 protocol client library"
arch=('i686' 'x86_64')
url="https://www.x.org/wiki/"
license=('custom')
depends=('glibc' 'libxcb' 'xorgproto')
makedepends=('git' 'xorg-util-macros' 'xtrans')
provides=("libx11=$pkgver")
conflicts=('libx11')
options=('staticlibs')
source=("git+https://gitlab.freedesktop.org/xorg/lib/libx11.git")
sha256sums=('SKIP')
pkgver() {
cd "libx11"
git describe --long --tags | sed 's/^libX11-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "libx11"
NOCONFIGURE=1 ./autogen.sh
./configure \
--prefix="/usr" \
--disable-xf86bigfont
make
}
check() {
cd "libx11"
make check
}
package() {
cd "libx11"
make DESTDIR="$pkgdir" install
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libx11"
}
|