summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fe6e4c251319965804f3841c9d6f71ab627bf099 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libxext-git
pkgver=1.3.4.r0.gebb167f
pkgrel=1
pkgdesc="X11 common extensions library"
arch=('i686' 'x86_64')
url="https://www.x.org/wiki/"
license=('custom')
depends=('glibc' 'libx11' 'xextproto')
makedepends=('git' 'xorg-util-macros')
provides=('libxext')
conflicts=('libxext')
options=('staticlibs')
source=("git+https://gitlab.freedesktop.org/xorg/lib/libxext.git")
sha256sums=('SKIP')


pkgver() {
  cd "libxext"

  git describe --long --tags | sed 's/^libXext-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libxext"

  NOCONFIGURE=1 ./autogen.sh
  ./configure \
    --prefix="/usr"
  make
}

check() {
  cd "libxext"

  make check
}

package() {
  cd "libxext"

  make DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libxext"
}