summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 71378adf6d45305ceb081b15744b43b9cbb22350 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libyaml-git
pkgver=0.1.7.r44.g660242d
pkgrel=2
pkgdesc="C library for parsing and emitting YAML"
arch=('i686' 'x86_64')
url="https://pyyaml.org/wiki/LibYAML"
license=('MIT')
depends=('glibc')
makedepends=('git')
provides=('libyaml')
conflicts=('libyaml')
options=('staticlibs')
source=("git+https://github.com/yaml/libyaml.git")
sha256sums=('SKIP')


pkgver() {
  cd "libyaml"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libyaml"

  ./bootstrap
  ./configure --prefix="/usr"
  make
}

check() {
  cd "libyaml"

  make check
}

package() {
  cd "libyaml"

  make DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/libyaml/LICENSE"
}