blob: ab104b8631c6194955c150398dc4d4fe46cdaa12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Konstantin Shalygin <k0ste@k0ste.ru>
# Contributor: Konstantin Shalygin <k0ste@k0ste.ru>
pkgname='libyang'
pkgver='1.0.109'
pkgrel='1'
pkgdesc='A YANG data modelling language parser and toolkit written (and providing API) in C.'
url="https://github.com/CESNET/${pkgname}"
arch=('x86_64')
license=('BSD')
depends=('pcre')
makedepends=('cmake')
checkdepends=('cmocka')
conflicts=('libyang-git' 'libyang-devel-git')
source=("${url}/archive/v${pkgver}.tar.gz")
sha256sums=('1686a381a8cce775102e60c8eb93f7ba64c6d4ae10591fc05d9f969a07815f60')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
mkdir build
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_BUILD_TYPE=Release \
-DENABLE_LYD_PRIV=ON \
-DENABLE_BUILD_TESTS=ON
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
make test
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
make DESTDIR="${pkgdir}" install
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|