PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libzip-git
pkgver=1.7.3.r79.g72b3722d
pkgrel=2
pkgdesc="C library for reading, creating, and modifying zip archives"
arch=('i686' 'x86_64')
url="https://libzip.org/"
license=('BSD')
depends=('glibc' 'bzip2' 'gnutls' 'openssl' 'xz' 'zlib' 'zstd')
makedepends=('git' 'cmake')
provides=('libzip')
conflicts=('libzip')
source=("git+https://github.com/nih-at/libzip.git")
sha256sums=('SKIP')


pkgver() {
  cd "libzip"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libzip"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    ./
  make -C "_build"
}

check() {
  cd "libzip"

  make -C "_build" check
}

package() {
  cd "libzip"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/libzip"
}