blob: 6dcacbadacfcef3465a16f6342b674f7a1ccac94 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://services.lidarr.audio/v1/update/nightly?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname="lidarr-nightly"
pkgver=0.7.1.1678
pkgrel=1
pkgdesc="Music download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/lidarr/Lidarr"
license=("GPL3")
depends=('sqlite' 'chromaprint')
options=('!strip' 'staticlibs')
optdepends=('sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'qbittorrent: torrent downloader'
'qbittorrent-nox: torrent downloader (no X)'
'jackett: torrent indexer proxy'
'libgdiplus: provides a gdi+ compatible api')
provides=('lidarr')
conflicts=('lidarr' 'lidarr-develop')
source_x86_64=("lidarr-${pkgver}-linux-core-x64.tar.gz::https://services.lidarr.audio/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("lidarr-${pkgver}-linux-core-arm64.tar.gz::https://services.lidarr.audio/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("lidarr-${pkgver}-linux-core-arm.tar.gz::https://services.lidarr.audio/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=('lidarr.service'
'lidarr.tmpfiles'
'lidarr.sysusers'
'package_info')
sha512sums=('e5858db23813a486c20c18bb66bf0fa1ca23361dd34d7b8ce12bbbbbc25daa744e0a41005c2ca7f2339e687dc8041ee64cbecfafa81b84d12445baa7d0c35f85'
'3800547b7c3d2b6e0a590ebd2db5ed48a6c31249098a4c36876faca36dd81e84ac45f3679d16bfe101be594dc6d5d0cfc91bfc66ed8cba35ec05f22027ab2441'
'ffd466960527256d8de1d9887d90d4da87486eff062950c46cbc4fd4af1ef89e7d5c070ef1e649b23a95fbab15651e289fd5bdc6d34649e4a6ecdf2f6da06622'
'9e052babfcaf9e4dee1adf85c2059f1bc3620e47adcb26e87ce0131b7240ef960741b17291f73395a6be7406669d90865b8d45e5c8c0e26045af73b3803331be')
sha512sums_x86_64=('03dc74a7e6c534926e254f0e3511254eff01084cc77b77320b749fde1a1cbd5087e63647ae61990dac99405f8c0114be240577a3c90ac3c202ead73062298934')
sha512sums_aarch64=('af562a7793d1366c25e305908ed6ec842ab02480769b2fca55d57b9a7852637750946d301e6a02272a8bfd4de223dfa8f3d824754b4099af607537df874df658')
sha512sums_armv7h=('1bf549ba0631f52229d410f6639ea15ec2fe08eb45e029f933936a46689444c2597fcce96b3a6e98d1d35fed44fd4ba87c3f8e6e85358ad157a9158ed7389afb')
package() {
# Update environment isn't needed.
rm -rf "${srcdir}/Lidarr/Lidarr.Update"
# The fpcalc binary comes from chromaprint.
rm -rf "${srcdir}/Lidarr/fpcalc"
install -d -m 755 "${pkgdir}/usr/lib/lidarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Lidarr/"* "${pkgdir}/usr/lib/lidarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/lidarr/bin"
chmod +x "${pkgdir}/usr/lib/lidarr/bin/Lidarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/lidarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/lidarr/package_info"
install -D -m 644 "${srcdir}/lidarr.service" "${pkgdir}/usr/lib/systemd/system/lidarr.service"
install -D -m 644 "${srcdir}/lidarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/lidarr.conf"
install -D -m 644 "${srcdir}/lidarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/lidarr.conf"
}
|