blob: b631ff3f86698b8c26b30b4895a1ceaf73cdcc4f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=light-locker-git
pkgver=1.7.0
pkgrel=1
pkgdesc='A simple session locker'
arch=('i686' 'x86_64')
url='https://github.com/the-cavalry/light-locker'
license=('GPL2')
depends=('dbus-glib' 'gtk3' 'libxss' 'libxxf86misc' 'lightdm')
makedepends=('git' 'gnome-common' 'intltool')
provides=('light-locker')
conflicts=('light-locker')
source=('git+https://github.com/the-cavalry/light-locker.git'
'light-locker-libsystemd-login.patch')
sha256sums=('SKIP'
'6645624e195f7cc114b95d323dfd55c03bbdf6b01de10e694df6a97d5ef6eeaf')
pkgver() {
cd light-locker
printf "%s" "$(git describe --tags | sed 's/-/.r/; s/-g/./; s/^v//')"
}
prepare() {
cd light-locker
patch -Np1 -i ../light-locker-libsystemd-login.patch
}
build () {
cd light-locker
./autogen.sh \
--prefix='/usr' \
--localstatedir='/var' \
--sysconfdir='/etc' \
--disable-schemas-compile \
--disable-static \
--with-{mit-ext,systemd,xf86gamma-ext,x} \
--without-{console-kit,upower}
make
}
package() {
cd light-locker
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|