blob: 7c827b5a4f74ebf02b9a969ff3e50f824573f19f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: sh4nks <sh4nks7@gmail.com
pkgname=lightdm-pantheon-greeter-git
pkgver=r770.8f93282
pkgrel=1
pkgdesc='Pantheon greeter for LightDM'
arch=('i686' 'x86_64')
url='https://github.com/elementary/greeter'
license=('GPL')
groups=('pantheon-unstable')
depends=('cairo' 'clutter' 'clutter-gtk' 'gdk-pixbuf2' 'glib2' 'glibc' 'gtk3'
'libgee' 'libgl' 'libx11' 'lightdm'
'libgranite.so' 'libwingpanel-2.0.so')
makedepends=('cmake' 'git' 'granite-git' 'libxfixes' 'vala' 'wingpanel-git')
provides=('lightdm-pantheon-greeter')
conflicts=('lightdm-pantheon-greeter')
replaces=('lightdm-pantheon-greeter-bzr')
install='lightdm-pantheon-greeter.install'
source=('lightdm-pantheon-greeter::git+https://github.com/elementary/greeter.git'
'lightdm-pantheon-greeter-paths.patch')
sha256sums=('SKIP'
'2277e4a11c8945b72cca0ab116aaae86099ccd90833c18b7f74b400f6f674b7f')
pkgver() {
cd lightdm-pantheon-greeter
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd lightdm-pantheon-greeter
patch -Np1 -i ../lightdm-pantheon-greeter-paths.patch
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
}
build() {
cd lightdm-pantheon-greeter/build
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DGSETTINGS_COMPILE='OFF'
make
}
package() {
cd lightdm-pantheon-greeter/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|