blob: 9d0521f82f29090a126b77a668ae6646b42f0db9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
# Taken from M0Rf30 morf3089 at gmail dot com
# Contributor: Michael Healy <horsemanoffaith@gmail.com>
# vercheck-pkgbuild: auto
# vercheck-ubuntu: name=${pkgname#*-}, repo=xenial
# vercheck-launchpad: name=${pkgname#*-}
pkgname=lightdm-unity-greeter
_ubuntu_rel=0ubuntu1
pkgver=16.04.0
pkgrel=1
pkgdesc="The greeter (login screen) application for Unity. It is implemented as a LightDM greeter."
arch=(i686 x86_64)
url="https://launchpad.net/unity-greeter"
license=(GPL3 LGPL3)
groups=(unity)
depends=(cantarell-fonts gnome-doc-utils ido libindicator3 lightdm-ubuntu
libcanberra libxext)
makedepends=(gnome-common gnome-doc-utils unity-settings-daemon imagemagick
intltool librsvg vala)
optdepends=("ubuntu-themes: Ubuntu's Ambiance and Radiance themes"
"ubuntu-wallpapers: Ubuntu's default wallpapers"
"ttf-ubuntu-font-family: Ubuntu's default font")
install=unity-greeter.install
source=("https://launchpad.net/ubuntu/+archive/primary/+files/${pkgname#*-}_${pkgver}-${_ubuntu_rel}.tar.xz"
spawn_indicators.patch
unity-greeter-indicators-start
10-unity.defaults
50-unity-greeter.rules
logo.png)
sha512sums=('3583def6d9ff337bf15d53bc6960528a454b387e6faabadf060a15b3c72e5645f9b091947acc14461007c7592953911d6ca7ce7e514a5a806f239a581e62d0bc'
'cf3a158061dd56c07b43f370e25590b8116bfd28e1bdab2a7a3d1ab6ec061884855f06007ea9eda9fd0d229506f73aceaabdc5ee0becc3aee070906e1f6fecd5'
'e43c177d0255af961bbf9198868e32a1a762bb70e117f80c3c2ce4b54d23f4955cc1c4c32b68751b021116f8e6d26133b24845c03ae459c2209e8313e28a0bc6'
'ee5d1f17dddd99ba55bbaca8aff5e8487c9b9f7e1eef570d2adb3d2519e19ef437b160414468ef85a8c1b14af1eee23c714e2086291701edfbab2f43064e2cd7'
'5d0f1b8221dfe02670df3ba88011dc0ce744bfd4205a9900dd8096de222358a740a384a47f13ed4e5b94e24d4a8ff5639117464c61a689dd7bd9025a0900f529'
'4cc7e3600a8f5afc7edf574ccdb21dbbff9c7492a46b50c696fb7b38446829f2cc99ae029688e289da2100a9cac6ae0471cc8bac03f8db3799f9929a1e2f2679')
prepare() {
cd "${pkgname#*-}-${pkgver}"
# Patch from unity-gentoo for spawning the indicator services since the
# DBus activation method is deprecated
patch -p1 -i ../spawn_indicators.patch
# Use Arch Linux logo (retain the same 245px height as the Ubuntu logo)
rm data/logo.png
# Stupid segfaulting imagemagick...
if ! convert -background none -resize 245 \
/usr/share/archlinux/logos/archlinux-mono-white.svg \
data/logo.png; then
cp ../logo.png data/logo.png
fi
}
build() {
cd "${pkgname#*-}-${pkgver}"
# Link against libm and libx11
export CFLAGS+=" -lm -lX11"
autoreconf -vfi
intltoolize -f
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--libexecdir=/usr/lib/lightdm
make || :
sed -i '1i#include <gtk/gtkx.h>' src/menubar.c
make
}
package() {
cd "unity-greeter-${pkgver}"
make DESTDIR="${pkgdir}" install
# Install PolicyKit file for allowing the lightdm user to use NetworkManager
# Note: PolicyKit no longer reads pkla files after version 0.107, so Ubuntu's
# policy file won't work.
install -dm700 "${pkgdir}/usr/share/polkit-1/rules.d/"
install -m644 "${srcdir}/50-unity-greeter.rules" \
"${pkgdir}/usr/share/polkit-1/rules.d/"
#install -dm700 "${pkgdir}/var/lib/polkit-1/"
#install -dm755 "${pkgdir}/var/lib/polkit-1/localauthority/10-vendor.d/"
#install -m644 "${srcdir}/debian/unity-greeter.pkla" \
# "${pkgdir}/var/lib/polkit-1/localauthority/10-vendor.d/"
# Install default GSettings/dconf settings for the guest account (requires
# lightdm-ubuntu).
install -dm755 "${pkgdir}/etc/guest-session/gsettings/"
install -m644 "${srcdir}/10-unity.defaults" \
"${pkgdir}/etc/guest-session/gsettings/"
# Install LightDM configuration file to set the Unity greeter as the default
install -dm755 "${pkgdir}/usr/share/lightdm/lightdm.conf.d/"
install -m644 debian/50-unity-greeter.conf \
"${pkgdir}/usr/share/lightdm/lightdm.conf.d/"
# Install unity-gentoo's script for launcher the indicator services
install -m755 "${srcdir}/unity-greeter-indicators-start" "${pkgdir}/usr/bin/"
# Use language packs
rm -r "${pkgdir}/usr/share/locale/"
}
|