blob: 15a6a0de27bfc85cb5899ac41829b39d6dda7472 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Conor Anderson <conor@conr.ca>
pkgname=lighttable-git
_pkgname="${pkgname%-git}"
_name=LightTable
pkgver=0.8.1.r49.g5db6b70
_pkgver=${pkgver/%.r*/}
pkgrel=1
pkgdesc='Next generation code editor and IDE with instant feedback.'
arch=('x86_64' 'i686')
url='http://lighttable.com/'
license=('MIT')
conflicts=('lighttable-bin')
depends=('alsa-lib' 'gconf' 'gtk2' 'java-environment' 'libnotify' 'nodejs' 'nss' 'libxtst')
makedepends=('npm' 'leiningen')
provides=('lighttable')
source=("git://github.com/LightTable/LightTable.git"
"lighttable.desktop")
sha256sums=('SKIP'
'3ed905cba2906c138016e53d9b9327bf933c8e96f649b50b3a479ec32045d1e1')
pkgver() {
cd "${srcdir}/${_name}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/${_name}"
script/build.sh
}
package() {
# Place files
install -d "${pkgdir}/usr/lib/${_pkgname}"
cp -a "${srcdir}/${_name}/builds/${_pkgname}-${_pkgver}-linux/"* "${pkgdir}/usr/lib/${_pkgname}"
# Symlink main binary
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/${_pkgname}/${_name}" "${pkgdir}/usr/bin/${_pkgname}"
# Place desktop entry and icon
desktop-file-install -m 644 --dir "${pkgdir}/usr/share/applications/" "${_pkgname}.desktop"
install -Dm644 "${srcdir}/${_name}/deploy/core/img/lticon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
# Place license files
for license in "LICENSE" "LICENSES.chromium.html"; do
install -Dm644 "${pkgdir}/usr/lib/${_pkgname}/${license}" "${pkgdir}/usr/share/licenses/${_pkgname}/${license}"
rm "${pkgdir}/usr/lib/${_pkgname}/${license}"
done
}
|