blob: dc105b594be9e1af4bef70d9f2ad61f61d17af97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
# Contributor: Slithery <aur [at] slithery [dot] uk>
pkgname=linode-cli
pkgver=5.24.0
_pkgver=4.138.0
pkgrel=5
pkgdesc="Linode API wrapper"
arch=('any')
url="https://github.com/${pkgname%%-*}/${pkgname}"
license=('BSD')
depends=('python-requests'
'python-setuptools'
'python-terminaltables'
'python-yaml')
makedepends=('python-build'
'python-installer'
'python-wheel')
optdepends=('python-boto: Object Storage plugin')
replaces=("${pkgname}-dev")
install="${pkgname}".install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz"
"${pkgname}-${_pkgver}-openapi.yaml::https://www.${pkgname%%-*}.com/docs/api/openapi.yaml")
sha512sums=('c016222bef85261c8f549bceff47408e501390cc38fe9aa228e8a59877525e742a63d8934529dc86035e9c41234df96af7f99826b714c2e6e5a609f56087a3df'
'28732e53932c02b060bf877a39591aa21a89b70bc37df1360fb2e71d5c671a1fd1583ba486aa73c6606986d7079d99459d61f6a755b4e03cf9b5253e467f096b')
prepare() {
cd "${pkgname}-${pkgver}"
# Manually set version number - thanks @the-k
sed -i "s/\(version=\)get_version()/\1\"${pkgver}\"/" setup.py
}
build() {
cd "${pkgname}-${pkgver}"
python -m linodecli bake "../${pkgname}-${_pkgver}-openapi.yaml" --skip-config
cp data-3 linodecli/
python -m build --wheel --no-isolation
}
package() {
cd "${pkgname}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -vDm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|