blob: 5c5033abc17526cf8df07d1e77898f958e86f16a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
# Contributor: Slithery <aur [at] slithery [dot] uk>
pkgname=linode-cli
pkgver=5.45.0
_pkgver=4.167.1
pkgrel=1
pkgdesc="Linode API wrapper"
arch=('any')
url="https://github.com/${pkgname%%-*}/${pkgname}"
license=('BSD')
depends=('python-openapi3'
'python-requests'
'python-setuptools'
'python-rich'
'python-yaml')
makedepends=('python-build'
'python-installer'
'python-wheel')
optdepends=('python-boto: Object Storage plugin')
replaces=("${pkgname}-dev")
install="${pkgname}".install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
"${pkgname}-${_pkgver}-openapi.yaml::https://www.${pkgname%%-*}.com/docs/api/openapi.yaml")
sha512sums=('05d0558647fa60deb3029b99b930a7f1a8dc153bba6842d84d137ab21767acdb719998a9ac837a5e54097589825617b0d81d046ed5b36b1b847448b621312d70'
'51bac12f462b382a682530ca65235513304e793c58cdfd0d2b8a940b5ce9b90ab042b7e36800eee0154ac6b566199bd49e10e1ad943db897ba8f0efa9870c361')
prepare() {
cd "${pkgname}-${pkgver}"
# Manually set version number - thanks @the-k
sed -i "s/\(version=\)version/\1\"${pkgver}\"/" setup.py
}
build() {
cd "${pkgname}-${pkgver}"
python \
-m linodecli bake "../${pkgname}-${_pkgver}-openapi.yaml" \
--skip-config
cp data-3 linodecli/
python -m build --wheel --no-isolation
}
package() {
cd "${pkgname}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -vDm0644 "${srcdir}/${pkgname}-${pkgver}/${pkgname}.sh" \
"${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|