blob: 5894a3a420a75e15258fbfe47e6bc61fbc2e79af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
# Contributor: Slithery <aur [at] slithery [dot] uk>
pkgname=linode-cli
pkgver=5.23.0
_pkgver=4.137.0
pkgrel=5
pkgdesc="Linode API wrapper"
arch=('any')
url="https://github.com/${pkgname%%-*}/${pkgname}"
license=('BSD')
depends=('python-requests'
'python-setuptools'
'python-terminaltables'
'python-yaml')
makedepends=('python-build'
'python-installer'
'python-wheel')
optdepends=('python-boto: Object Storage plugin')
replaces=("${pkgname}-dev")
install="${pkgname}".install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz"
"${pkgname}-${_pkgver}-openapi.yaml::https://www.${pkgname%%-*}.com/docs/api/openapi.yaml")
sha512sums=('1db1bba6bb256a7f75b7117113e14cad1838a8fa20585d78d799d1717530842553f74ffab1a97bd7e2fde1bfa847172e0f3459a07c7dfd59d420e9b46d1cafdd'
'fcd630c379a5e9fb93e36c67d4d35762b1a6416e1ae9b7b21679c794a7f65fc731435731f13d4682d295f0dc365c86f9e0d657652de315aeb35ff9fd1ebdc3b2')
prepare() {
cd "${pkgname}-${pkgver}"
# Manually set version number - thanks @the-k
sed -i "s/\(version=\)get_version()/\1\"${pkgver}\"/" setup.py
}
build() {
cd "${pkgname}-${pkgver}"
python -m linodecli bake "../${pkgname}-${_pkgver}-openapi.yaml" --skip-config
cp data-3 linodecli/
python -m build --wheel --no-isolation
}
package() {
cd "${pkgname}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -vDm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|