blob: 9fc6bdc081c57e452f938231802940de7459b888 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
# Contributor: Slithery <aur [at] slithery [dot] uk>
pkgname=linode-cli
pkgver=5.38.0
_pkgver=4.153.0
pkgrel=1
pkgdesc="Linode API wrapper"
arch=('any')
url="https://github.com/${pkgname%%-*}/${pkgname}"
license=('BSD')
depends=('python-requests'
'python-setuptools'
'python-rich'
'python-yaml')
makedepends=('python-build'
'python-installer'
'python-wheel')
optdepends=('python-boto: Object Storage plugin')
replaces=("${pkgname}-dev")
install="${pkgname}".install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
"${pkgname}-${_pkgver}-openapi.yaml::https://www.${pkgname%%-*}.com/docs/api/openapi.yaml")
sha512sums=('0b32321115820d09033e7e623ee80f0899e1fd1c6a617f2e7f261cff4c2b547b260e0c96730681487e40fe94adbd875b602b55acc6ec4c73061585940175d529'
'1f3314d995f9e598d6d77e292f06a45c36a9b02879c7f564855318177748f63ddd1eb844999b425fb9f2f21c05d515e16d53d3e9a82af3efcbac5e5d89436540')
prepare() {
cd "${pkgname}-${pkgver}"
# Manually set version number - thanks @the-k
sed -i "s/\(version=\)version/\1\"${pkgver}\"/" setup.py
}
build() {
cd "${pkgname}-${pkgver}"
python -m linodecli bake "../${pkgname}-${_pkgver}-openapi.yaml" --skip-config
cp data-3 linodecli/
python -m build --wheel --no-isolation
}
package() {
cd "${pkgname}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -vDm0644 "${srcdir}/${pkgname}-${pkgver}/${pkgname}.sh" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|