blob: de4b8d5bf8ce2ef36eddeda6bc006679b48735e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
# Contributor: Slithery <aur [at] slithery [dot] uk>
pkgname=linode-cli
pkgver=5.41.2
_pkgver=4.157.1
pkgrel=1
pkgdesc="Linode API wrapper"
arch=('any')
url="https://github.com/${pkgname%%-*}/${pkgname}"
license=('BSD')
depends=('python-requests'
'python-setuptools'
'python-rich'
'python-yaml')
makedepends=('python-build'
'python-installer'
'python-wheel')
optdepends=('python-boto: Object Storage plugin')
replaces=("${pkgname}-dev")
install="${pkgname}".install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
"${pkgname}-${_pkgver}-openapi.yaml::https://www.${pkgname%%-*}.com/docs/api/openapi.yaml")
sha512sums=('18944cd82cd049dda9da9db97dd74a4d4c863e219c333e6ff3c26d51c6b5316541b17dd31d30d6ce76612b4dcf5a925481086eafc16108dbb1b628b68e313a63'
'2796378b1d4f70e64ff69b88dc836713caad5e3026dd367f5d6e4ba2279db9aef1ddcf8d3d7c7b6955076537b41226c0aa79a60f6c9e4bae6ec4a267209c9434')
prepare() {
cd "${pkgname}-${pkgver}"
# Manually set version number - thanks @the-k
sed -i "s/\(version=\)version/\1\"${pkgver}\"/" setup.py
}
build() {
cd "${pkgname}-${pkgver}"
python -m linodecli bake "../${pkgname}-${_pkgver}-openapi.yaml" --skip-config
cp data-3 linodecli/
python -m build --wheel --no-isolation
}
package() {
cd "${pkgname}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -vDm0644 "${srcdir}/${pkgname}-${pkgver}/${pkgname}.sh" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|