summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7328591ba88dd0bc1d75ff0ef2119bcda64568b1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Adrian Lopez <zeioth@hotmail.com>
# Maintainer: txtsd <aur.archlinux@ihavea.quest>

pkgname=linux-command-gpt-git
_pkgname=linux-command-gpt
pkgver=v0.1.2.r0.g952eee1
pkgrel=2
pkgdesc='Get Linux commands in natural language with the power of ChatGPT'
arch=('x86_64' 'aarch64')
url='https://github.com/asrul10/linux-command-gpt'
license=('MIT')
depends=('glibc')
makedepends=('git' 'go')
provides=('linux-command-gpt')
conflicts=('linux-command-gpt')
source=("git+${url}")
sha256sums=('SKIP')

pkgver() {
    cd "${_pkgname}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${_pkgname}"
    # https://wiki.archlinux.org/index.php/Go_package_guidelines
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOPATH="${srcdir}/go"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
    go build -o lcg
}

check() {
  cd "${_pkgname}"
  go test ./...
}

package() {
    cd "${_pkgname}"
    install -Dm755 "lcg" "${pkgdir}/usr/bin/lcg"
    install -Dm755 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}