blob: 34be841e59ef1e8c19c16064436e6f8cee0087cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Maintainer: Chris Billington <chrisjbillington@gmail.com>
_pkgname=linux
_kernver=5.9.12
_archver=arch1
_pkgrel=1
_pkgver="${_kernver}.${_archver}"
pkgbase="${_pkgname}-versioned-bin"
KERNNAME="${_kernver}-${_archver}-${_pkgrel}"
_versioned_pkgname="${_pkgname}${_pkgver}-${_pkgrel}"
pkgname=("${_pkgname}-versioned-bin"
"${_pkgname}-versioned-headers-bin"
"${_pkgname}-versioned-docs-bin"
"${_versioned_pkgname}-bin"
"${_versioned_pkgname}-headers-bin"
"${_versioned_pkgname}-docs-bin")
pkgver=${_pkgver}
pkgrel=${_pkgrel}
pkgdesc='Repackaging of the Arch kernel with a unique package name for each version'
url="https://git.archlinux.org/linux.git/log/?h=v${_kernver}-${_archver}"
arch=(x86_64)
license=(GPL2)
options=('!strip')
_kernpkg=${_pkgname}-${_pkgver}-${_pkgrel}-${arch}.pkg.tar.zst
_headerspkg=${_pkgname}-headers-${_pkgver}-${_pkgrel}-${arch}.pkg.tar.zst
_docspkg=${_pkgname}-docs-${_pkgver}-${_pkgrel}-${arch}.pkg.tar.zst
# See if the sources are available from our own mirror:
_kernsrc=$(pacman -Sp "${_pkgname}" 2> /dev/null)
_headerssrc=$(pacman -Sp "${_pkgname}-headers" 2> /dev/null)
_docssrc=$(pacman -Sp "${_pkgname}-docs" 2> /dev/null)
# If not, then use the Arch Linux archive:
if [ "$(basename "${_kernsrc}" 2> /dev/null)" != "${_kernpkg}" ]; then
_arch_archive=https://archive.archlinux.org/packages/.all
_kernsrc=${_arch_archive}/${_kernpkg}
_headerssrc=${_arch_archive}/${_headerspkg}
_docssrc=${_arch_archive}/${_docspkg}
fi
source=("${_kernsrc}"
"${_headerssrc}"
"${_docssrc}")
sha256sums=('95c9bec2620306da7b185fa911f22310f4f6abfc901870df020ba156cc321715'
'3cbf07112cbd7cc4268a3b56f5311ccb3a2627423ea1fa871de80166c9c0ce1c'
'2a03fdaf7ce2b2e4d22ca55ebfebaaefbe068d05c42cf2080f509925e0a689aa')
package_linux-versioned-bin() {
pkgdesc="Dummy package depending on ${_versioned_pkgname}-bin"
depends=("${_versioned_pkgname}-bin")
optdepends=('grub-hook: to run grub-mkconfig when kernels are added/removed')
}
package_linux-versioned-headers-bin() {
pkgdesc="Dummy package depending on ${_versioned_pkgname}-headers-bin"
depends=("${_versioned_pkgname}-headers-bin")
}
package_linux-versioned-docs-bin() {
pkgdesc="Dummy package depending on ${_versioned_pkgname}-docs-bin"
depends=("${_versioned_pkgname}-docs-bin")
}
package_linux5.9.12.arch1-1-bin() {
pkgdesc="The Linux kernel and modules, version ${KERNNAME}"
depends=(coreutils kmod initramfs)
conflicts=("${_pkgname}")
optdepends=('crda: to set the correct wireless channels of your country'
'linux-firmware: firmware images needed for some devices')
provides=(VIRTUALBOX-GUEST-MODULES WIREGUARD-MODULE)
replaces=(virtualbox-guest-modules-arch wireguard-arch)
tar -xf "${_kernpkg}" -C "${pkgdir}"
rm "${pkgdir}"/{.MTREE,.BUILDINFO,.PKGINFO}
sed -ic "s/${_pkgname}/${KERNNAME}/" "${pkgdir}/usr/lib/modules/${KERNNAME}/pkgbase"
}
package_linux5.9.12.arch1-1-headers-bin() {
pkgdesc="Headers and scripts for building modules for the Linux kernel ${KERNNAME}"
conflicts=("${_pkgname}-headers")
tar -xf "${_headerspkg}" -C "${pkgdir}"
rm "${pkgdir}"/{.MTREE,.BUILDINFO,.PKGINFO}
mv "${pkgdir}/usr/src/"{"${_pkgname}","${_versioned_pkgname}"}
}
package_linux5.9.12.arch1-1-docs-bin() {
pkgdesc="Documentation for the Linux kernel ${KERNNAME}"
conflicts=("${_pkgname}-docs")
tar -xf "${_docspkg}" -C "${pkgdir}"
rm "${pkgdir}"/{.MTREE,.BUILDINFO,.PKGINFO}
mv "${pkgdir}/usr/share/doc/"{"${_pkgname}","${_versioned_pkgname}"}
}
|