PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Alexis Maiquez <aur@almamu.com>
pkgname=linux-wallpaperengine-core-git
_pkgname=linux-wallpaperengine
pkgver=r660.76a5fd3
pkgrel=1
pkgdesc="linux-wallpaperengine backend code, handles rendering of wallpapers for the various frontends out there"
arch=('x86_64')
url="https://github.com/Almamu/linux-wallpaperengine-core"
license=('GPL-3.0-only')
depends=('lz4' 'ffmpeg' 'mpv' 'glfw' 'glew' 'freeglut' 'libpulse' 'libcups' 'at-spi2-core' 'nss' 'libxcomposite' 'libxdamage' 'nspr')
makedepends=('git' 'cmake' 'sdl2' 'glm')
provides=("linux-wallpaperengine-core" "linux-wallpaperengine-webhelper")
source=("${pkgname}::git+https://github.com/Almamu/linux-wallpaperengine-core.git#branch=main")
sha512sums=('SKIP')

pkgver() {
    cd "$pkgname"
        ( set -o pipefail
          git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
          printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
        )
}

prepare() {
    cd "$pkgname"
    git submodule update --init src/External/glslang-WallpaperEngine
    git submodule update --init src/External/json
    git submodule update --init src/External/kissfft-WallpaperEngine
    git submodule update --init src/External/MimeTypes
    git submodule update --init src/External/quickjs
    git submodule update --init src/External/SPIRV-Cross-WallpaperEngine
    git submodule update --init src/External/stb
    git -c protocol.file.allow=always submodule update
}

build() {
    cmake -B build -S "$pkgname" \
        -DCMAKE_BUILD_TYPE='Release' \
        -DCMAKE_INSTALL_PREFIX="/usr" \
        -Wno-dev \
        -DCMAKE_CXX_FLAGS="-ffat-lto-objects -Wno-builtin-macro-redefined" \
        -DCMAKE_C_FLAGS="-Wno-builtin-macro-redefined"
    cmake --build build --target linux-wallpaperengine-core linux-wallpaperengine-webhelper
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}