blob: cf50d3e0e73dcb60913cb379edc465ec736a4d65 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Maintainer: Joan Figueras <ffigue at gmail dot com>
# Contributor: Torge Matthies <openglfreak at googlemail dot com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: SoftExpert <softexpert at gmail dot com>
_arch=x64v1
_pkgbase=linux-xanmod
_major=6.3
_minor=8
_branch=6.x
_xanmodrel=1
_xanmodrev=
pkgrel=1
pkgbase=${_pkgbase}-linux-bin-${_arch}
pkgver=${_major}.${_minor}
pkgname=("${pkgbase}" "${_pkgbase}-linux-headers-bin-${_arch}")
pkgdesc="The Linux kernel and modules with Xanmod patches - Current Stable (MAIN) - Prebuilt version - ${_arch}"
url="http://www.xanmod.org/"
arch=(x86_64)
license=(GPL2)
options=('!strip')
makedepends=('jq' 'curl')
# Resolve URL of sources from GiHub provider
# cache the response of the API to reduce the number of calls made to GitHub; not authenticated calls are limited to 60 per hour
_json_data=$(curl -L -s https://api.github.com/repos/xanmod/linux/releases/tags/${pkgver}-xanmod${_xanmodrel}${_xanmodrev})
_url_image=$(echo "${_json_data}" | jq --arg PKGVER "${pkgver}" --arg PKGREL "${_xanmodrel}" --arg ARCH "${_arch}" -r '.assets[] | select(.name | startswith("linux-image-" + $PKGVER + "-" + $ARCH + "-xanmod" + $PKGREL) and endswith(".deb")).browser_download_url')
_url_headers=$(echo "${_json_data}" | jq --arg PKGVER "${pkgver}" --arg PKGREL "${_xanmodrel}" --arg ARCH "${_arch}" -r '.assets[] | select(.name | startswith("linux-headers-" + $PKGVER + "-" + $ARCH + "-xanmod" + $PKGREL) and endswith(".deb")).browser_download_url')
source=("${_url_image}" "${_url_headers}")
noextract=("${_url_image}" "${_url_headers}")
# Save files we will extract later manually
_file_image="${_url_image##*/}"
_file_headers="${_url_headers##*/}"
prepare() {
bsdtar -xf ${_file_image} data.tar.xz
bsdtar -xf data.tar.xz
rm -f data.tar.xz
bsdtar -xf ${_file_headers} data.tar.xz
bsdtar -xf data.tar.xz
rm -f data.tar.xz
}
validpgpkeys=(
'ABAF11C65A2970B130ABE3C479BE3E4300411886' # Linux Torvalds
'647F28654894E3BD457199BE38DBBDC86092693E' # Greg Kroah-Hartman
)
sha256sums=('8345875ccab157bc21174811143a20fa439092e5e465baa454943f2b1d9cbc79'
'175a3f2f7c0959987b94ab894f24df661a5a3cb5b430f8973f8a101bb573bbc4')
_package() {
pkgdesc="The Linux kernel and modules with Xanmod patches - Current Stable (MAIN) - Prebuilt version - ${_arch}"
depends=(coreutils kmod initramfs)
optdepends=('crda: to set the correct wireless channels of your country'
'linux-firmware: firmware images needed for some devices')
provides=(VIRTUALBOX-GUEST-MODULES
WIREGUARD-MODULE
KSMBD-MODULE
NTFS3-MODULE)
local kernver="${pkgver}-${_arch}-xanmod${_xanmodrel}"
local modulesdir="${pkgdir}/usr/lib/modules/${kernver}"
mkdir -p "${modulesdir}" "${pkgdir}/usr/share/doc"
mkdir -p "${pkgdir}"/{boot,usr/lib/modules}
msg2 "Installing modules..."
cp -r lib/modules/${kernver}/* "${modulesdir}/"
# Docs
cp -r usr/share/doc/linux-image-* "${pkgdir}/usr/share/doc/"
msg2 "Installing boot image..."
# systemd expects to find the kernel here to allow hibernation
# https://github.com/systemd/systemd/commit/edda44605f06a41fb86b7ab8128dcf99161d2344
install -Dm644 "boot/vmlinuz-${kernver}" "${modulesdir}/vmlinuz"
# Used by mkinitcpio to name the kernel
echo "${pkgbase}" | install -Dm644 /dev/stdin "${modulesdir}/pkgbase"
echo "${kernver}" | install -Dm644 /dev/stdin "${modulesdir}/kernelbase"
# write kernel version for Grub
echo "${kernver}${_xanmodrev}" | install -Dm644 /dev/stdin "${pkgdir}/boot/${pkgbase}.kver"
local _extramodules="extramodules-${kernver}"
ln -s "../${_extramodules}" "${modulesdir}/extramodules"
# add real version for building modules and running depmod from hook
echo "${kernver}" | install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modules/${_extramodules}/version"
# now we call depmod...
# depmod -b "${pkgdir}/usr" -F "${srcdir}/boot/System.map-${kernver}"
}
_package-headers() {
pkgdesc="Headers and scripts for building modules for the Linux Xanmod - Current Stable (MAIN) - Prebuilt version - ${_arch}"
depends=(pahole)
mkdir -p "${pkgdir}"/usr/share/doc
cp -r usr/share/doc/linux-headers-* "${pkgdir}/usr/share/doc/"
cp -r usr/src "${pkgdir}/usr/"
}
eval "package_${pkgname[0]}() { _package \"\$@\"; }"
eval "package_${pkgname[1]}() { _package-headers \"\$@\"; }"
# vim:set ts=8 sts=2 sw=2 et:
|