PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>

pkgname=liri-workspace-git
pkgver=20161009.b5dba67
pkgrel=1
pkgdesc="Liri workspace, programs and plugins"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="http://liri.io"
license=('GPL3')
depends=('qt5-tools' 'qt5-gstreamer' 'greenisland-git' 'vibe-git' 'glib2' 'dconf'
         'paper-icon-theme-git' 'ttf-dejavu' 'ttf-droid' 'noto-fonts')
makedepends=('git' 'extra-cmake-modules' 'boost')
conflicts=('hawaii-workspace-git' 'liri-workspace')
replaces=('hawaii-workspace-git' 'liri-workspace')
provides=('liri-workspace')
groups=('liri-git')
install=$pkgname.install

_gitroot="git://github.com/lirios/workspace.git"
_gitbranch=release/0.9.0
_gitname=workspace
source=(${_gitname}::${_gitroot}#branch=${_gitbranch})
md5sums=('SKIP')

pkgver() {
	cd ${srcdir}/${_gitname}
	echo "$(git log -1 --format="%cd" --date=short | tr -d '-').$(git log -1 --format="%h")"
}

prepare() {
	mkdir -p build
}

build() {
	cd build
	cmake ../${_gitname} \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=Release \
		-DKDE_INSTALL_LIBDIR=lib \
		-DKDE_INSTALL_LIBEXECDIR=lib
	make
}

package() {
	cd build
	make DESTDIR="${pkgdir}" install
}