blob: 268a0775f4961355e7a8c25c54039ebdc7520cf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Andrej Radović <r.andrej@gmail.com>
_name=litecli
pkgname=${_name}-git
pkgver=v1.13.0.r157.gf4c3052
pkgrel=1
pkgdesc="A command-line client for SQLite databases that has auto-completion ""\
and syntax highlighting."
url="https://github.com/dbcli/litecli"
arch=(any)
license=('BSD')
depends=(
'python'
'python-click'
'python-pygments'
'python-prompt_toolkit'
'python-sqlparse'
'python-configobj'
'python-cli_helpers'
'python-llm'
)
makedepends=(python-build python-installer python-wheel python-setuptools python-setuptools-scm)
source=("git+https://github.com/dbcli/litecli.git")
md5sums=('SKIP')
provides=('litecli')
conflicts=('litecli')
pkgver() {
cd "$_name"
(
set -o pipefail
git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
)
}
build() {
cd "$srcdir/${_name}"
rm -rf build/ dist/ *.egg-info/
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir/${_name}"
python -m installer --destdir="$pkgdir" dist/litecli-*.whl
install -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|