blob: ffd372c8c1f47e54ca7cc9298031815885f288fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Remi Gacogne <rgacogne(at)archlinux(dot)org>
_pkgbase=lkrg
pkgname=lkrg-dkms
pkgver=0.9.5
pkgrel=1
pkgdesc='Linux Kernel Runtime Guard (DKMS)'
arch=('any')
url='https://lkrg.org/'
license=('GPL2')
source=("${url}/download/${_pkgbase}-${pkgver}.tar.gz"
"${url}/download/${_pkgbase}-${pkgver}.tar.gz.sign"
'dkms.conf')
sha512sums=('ae735f14bcb92e964a2a1d4cf11f44d8589ebf7b09634799ce38f2b27e9df9eb53e6dc00818df743a20de947ea402dcdcd8bee274b0954addf742547333d939a'
'SKIP'
'8101dd415ed08edd455989a9b10a3c925b171d3375a6d6872f55805d9aeb355a4ac216cce11afc1b84eeb49de0771932005d74130ffd6f5cdea9fa53fb4f9506')
validpgpkeys=('297AD21CF86C948081520C1805C027FD4BDC136E')
depends=('dkms')
prepare() {
# Set version
cp dkms.conf "${_pkgbase}-${pkgver}"
sed -e "s/@PKGVER@/${pkgver}/" \
-i "${_pkgbase}-${pkgver}/dkms.conf"
}
package() {
# Copy sources (including Makefile)
mkdir -p "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/"
cp -r "${_pkgbase}-${pkgver}"/* "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/"
find "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/" -type f -exec chmod 644 {} \;
find "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/" -type d -exec chmod 755 {} \;
# Copy OUR dkms.conf
install -Dm644 "${_pkgbase}-${pkgver}/dkms.conf" "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/dkms.conf"
}
|